# Laplace double exponential distribution, kurtosis 3
laplace(x) = exp(-abs(x)*sqrt(2)) * sqrt(0.5)

# sech distribution, kurtosis 2
sech(x) = 2.0 / (exp(x) + exp(-x))
sech_pdf(x) = 0.5 * sech(0.5*pi*x)

# logistic distribution, kurtosis 1.2
slogist = sqrt(3) / pi
logist(x) = exp(-x/slogist) / slogist / (1 + exp(-x/slogist))**2

# normal distribution, kurtosis 0
n(x) = exp(-0.5*x*x) / sqrt(2*pi)

# raised cosine distribution, kurtosis -0.59376
scos = 1.0 / sqrt(1/3.0 - 2/pi**2)
cosine(x) = abs(x)>scos? 0 : (1+cos(x*pi/scos))*0.5/scos

# Wigner semicircle distribution, kurtosis -1
wigner(x) = abs(x)>2? 0 : sqrt(4-x*x)*0.5/pi

# uniform distribution, kurtosis -1.2
uniform(x) = abs(x)>sqrt(3)? 0 : 0.5/sqrt(3)

set samples 6001
set grid

set xrange [-5.4:5.4]
set xtics 1

set key right font ",8" enhanced

set terminal svg size 400,300 enhanced fname 'DejaVu Sans'  fsize 10 butt solid
set output 'Standard symmetric pdfs.svg'

plot \
     laplace(x)  lt 1 lw 2 title "D,  3", \
     sech_pdf(x) lt 8 lw 2 title "S,  2", \
     logist(x)   lt 2 lw 2 title "L,  1.2", \
     n(x)        lt 7 lw 2 title "N,  0", \
     cosine(x)   lt 5 lw 2 title "C, -0.59376", \
     wigner(x)   lt 3 lw 2 title "W, -1", \
     uniform(x)  lt 4 lw 2 title "U, -1.2"